# $Id: PKGBUILD 50073 2011-06-23 20:50:24Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Kessia 'even' Pinheiro <kessiapinheiro at gmail.com>
# Contributor: Sorin Ionescu <sorin.ionescu@gmail.com>

pkgname=ufw
pkgver=0.30.1
pkgrel=1
pkgdesc="Uncomplicated and easy to use CLI tool for managing a netfilter firewall"
arch=('any')
url="https://launchpad.net/ufw"
license=('GPL3')
depends=('iptables' 'python2')
backup=('etc/ufw/before.rules'
        'etc/ufw/before6.rules'
        'etc/ufw/after.rules'
        'etc/ufw/after6.rules'
        'etc/ufw/ufw.conf'
        'etc/ufw/user.rules'
        'etc/ufw/sysctl.conf'
        'etc/default/ufw'
        'lib/ufw/user.rules'
        'lib/ufw/user6.rules')
changelog=$pkgname.changelog
source=(http://launchpad.net/${pkgname}/0.30/${pkgver}/+download/${pkgname}-${pkgver}.tar.gz \
        $pkgname.rc)
sha256sums=('98da13fe3e9aa8ff29611f20ef6e8b15be42bcdc43c8ef3145755b220f3bae1a'
            '2a59d28b7be47e65dc5310e595b0185e7882581a7671753a676252738a4c3847')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

  python2 setup.py install --root=${pkgdir}

  install -Dm755 ${srcdir}/$pkgname.rc ${pkgdir}/etc/rc.d/$pkgname

  install -D -m755 ${pkgdir}/usr/sbin/$pkgname ${pkgdir}/usr/bin/$pkgname
  rm -rf ${pkgdir}/usr/sbin
  chmod 644 ${pkgdir}/etc/ufw/*.rules ${pkgdir}/lib/ufw/*.rules
}