Spis treści
Indeks 🔎︎

# Funkcje matematyczne

Ta kategoria zawiera funkcje matematyczne programu Calc. Aby otworzyć Kreator funkcji, wybierz polecenie Wstaw - Funkcja.

## AGREGUJ

Zwraca wyniki agregacji obliczeń w zakresie. Dostępne są różne funkcje agregacji z listy poniżej. Funkcja agregacji pozwala pominąć ukryte wiersze, błędy SUMY.CZĘŚCIOWE i inne wyniki funkcji AGREGUJ w obliczeniach.

## ODEJMOWANIE

Odejmuje zestaw liczb i podaje wynik bez eliminowania drobnych błędów zaokrąglania.

## KOLOR

Zwraca wartość numeryczną obliczoną przez kombinację trzech kolorów (czerwony, zielony i niebieski) oraz przez kanał alfa w systemie kolorów RGBA. Wynik zależy od koloru systemowego użytego w systemie.

## SUMIFS

Zwraca sumę wartości komórek w zakresie, który spełnia wielokrotność kryteriów w wielokrotności zakresów.

## ACOS

Zwraca arcus cosinus liczby.

#### Składnia

ACOS(Liczba)

Ta funkcja zwraca arcus cosinus z Liczba, czyli kąt (w radianach), którego cosinus jest Liczba. Zwrócony kąt jest między 0 a Pi.

Aby uzyskać wartość kąta w stopniach, zastosuj funkcję STOPNIE.

#### Przykład

=ACOS(-1) zwraca wartość 3,14159265358979 (PI radianów)

=STOPNIE(ACOS(0,5)) zwraca wartość 60. Cosinus kąta 60 stopni wynosi 0,5.

## ACOSH

Zwraca arcus cosinus hiperboliczny liczby.

#### Składnia

ACOSH(Liczba)

Ta funkcja zwraca arcus cosinus hiperboliczny z Liczby, to liczba, której cosinus hiperboliczny jest Liczba.

Liczba musi być większa lub równa 1.

#### Przykład

=ACOSH(1) zwraca wartość 0.

=ACOSH(COSH(4)) zwraca wartość 4.

## ACOT

Zwraca arcus cotangens podanej liczby.

#### Składnia

ACOT(Liczba)

Ta funkcja zwraca arcus cotangens z Liczba, czyli kąt (w radianach), którego cotangens jest Liczba. Zwrócony kąt jest między 0 a Pi.

Aby uzyskać wartość kąta w stopniach, zastosuj funkcję STOPNIE.

#### Przykład

=ACOT(1) zwraca wartość 0,785398163397448 (PI/4 radianów).

=STOPNIE(ACOT(1)) zwraca wartość 45. Tangens kąta 45 stopni wynosi 1.

## ACOTH

Zwraca arcus cotangens hiperboliczny podanej liczby.

#### Składnia

ACOTH(Liczba)

Funkcja ta zwraca odwrotny cotangens hiperboliczny z parametru Liczba, czyli wartość, dla której odwrotny cotangens hiperboliczny wynosi parametr Liczba.

Jeśli liczba zawiera się w przedziale od -1 do 1 włącznie, wystąpi błąd.

#### Przykład

=ACOTH(1,1) zwraca odwrotny cotangens hiperboliczny z 1,1, czyli ok. 1,52226.

## ASIN

Zwraca arcus sinus podanej liczby.

#### Składnia

ASIN (Liczba)

Ta funkcja zwraca arcus sinus z Liczba, czyli kąt (w radianach), którego sinus jest Liczba. Zwrócony kąt jest między -PI/2 a +Pi/2.

Aby uzyskać wartość kąta w stopniach, zastosuj funkcję STOPNIE.

#### Przykład

=ASIN(0) zwraca wartość 0.

=ASIN(1) zwraca wartość 1,5707963267949 (PI/2 radianów).

=STOPNIE(ASIN(0,5)) zwraca wartość 30. Sinus kąta 30 stopni wynosi 0,5.

## ASINH

Zwraca arcus sinus hiperboliczny liczby.

#### Składnia

ASINH(Liczba)

Funkcja ta zwraca arcus sinus hiperboliczny z parametru Liczba, czyli wartość, dla której arcus sinus hiperboliczny wynosi parametr Liczba.

#### Przykład

=ASINH(-90) zwraca wartość ok. -5,1929877.

=ASINH(SINH(4)) zwraca wartość 4.

## ATAN

Zwraca arcus tangens liczby.

#### Składnia

ATAN(Liczba)

Ta funkcja zwraca arcus tangens z Liczba, czyli kąt (w radianach), którego tangens jest Liczba. Zwrócony kąt jest między -PI/2 a +Pi/2.

Aby uzyskać wartość kąta w stopniach, zastosuj funkcję STOPNIE.

#### Przykład

=ATAN(1)zwraca wartość 0,785398163397448 (PI/4 radianów).

=STOPNIE(ATAN(1)) zwraca wartość 45. Tangens kąta 45 stopni wynosi 1.

## ATAN2

Returns the angle (in radians) between the x-axis and a line from the origin to the point (NumberX|NumberY).

Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)

#### Składnia

ATAN2(Liczba x; Liczba y)

NumberX is the value of the x coordinate.

Liczba_Y jest wartością współrzędnej Y.

Programming languages have usually the opposite order of arguments for their atan2() function.

ATAN2 returns the angle (in radians) between the x-axis and a line from the origin to the point (NumberX|NumberY)

#### Przykład

=ATAN2(-5;9) returns 2.07789 radians.

To get the angle in degrees apply the DEGREES function to the result.

=DEGREES(ATAN2(12.3;12.3)) returns 45. The tangent of 45 degrees is 1.

LibreOffice results 0 for ATAN2(0;0).

The function can be used in converting cartesian coordinates to polar coordinates.

=DEGREES(ATAN2(-8;5)) returns φ = 147.9 degrees

## ATANH

Zwraca arcus tangens hiperboliczny liczby.

#### Składnia

ATANH(Liczba)

Funkcja ta zwraca arcus tangens hiperboliczny z parametru Liczba, czyli wartość, dla której arcus tangens hiperboliczny wynosi parametr Liczba.

Liczba musi spełniać warunek -1 < liczba < 1.

#### Przykład

=ATANH(0) zwraca wartość 0.

## COS

Zwraca cosinus podanej liczby (kąta).

#### Składnia

COS(Liczba)

Zwraca cosinus (trygonometryczny) z Liczba, kąta wyrażonego w radianach.

Aby uzyskać cosinus kąta w stopniach, zastosuj funkcję RADIANY.

#### Przykład

=COS(PI()*2) zwraca 1 ― cosinus kąta o mierze równej PI*2 radianów.

=COS(RADIANY(60)) zwraca wartość 0,5, czyli cosinus kąta 60 stopni.

## COSH

Zwraca cosinus hiperboliczny liczby.

#### Składnia

COSH(Liczba)

Zwraca cosinus hiperboliczny z Liczba.

#### Przykład

=COSH(0) zwraca wartość 1, cosinus hiperboliczny liczby 0.

## COT

Zwraca cotangens argumentu traktowanego jako miara kąta w radianach.

#### Składnia

COT(Liczba)

Zwraca cotangens (trygonometryczny) z Liczba, kąta wyrażonego w radianach.

Aby uzyskać cotangens kąta w stopniach, zastosuj funkcję RADIANY.

Cotangens kąta jest równy odwrotności tangensa kąta.

### Przykład:

=COT(PI()/4) zwraca wartość 1 ― cotangens kąta o mierze PI/4 radianów.

=COT(RADIANY(45)) zwraca wartość 1, cotangens kąta 45 stopni.

## COTH

Zwraca cotangens hiperboliczny podanej liczby (kąta).

#### Składnia

COTH(Liczba)

Zwraca cotangens hiperboliczny z Liczba.

#### Przykład

=COTH(1) zwraca cotangens hiperboliczny z liczby 1 czyli ok. 1,3130.

## CSC

Zwraca cosecant podanego kąta (w radianach). Cosecant jest równy 1 dzielone przez sinus tego kąta.

This function is available since LibreOffice 3.5.

#### Składnia

CSC(Liczba)

Zwraca (trygonometryczny) cosecans z Liczby, kąta w radianach.

Aby uzyskać cosecans kąta w stopniach, zastosuj funkcję RADIANY.

#### Przykład

=CSC(PI()/4) zwraca w przybliżeniu 1.4142135624, odwrotność sinusa z PI/4 radianów.

=CSC(RADIANY(30)) zwraca 2, cosecans 30 stopni.

## CSCH

Zwraca hiperboliczny cosecans z liczby.

This function is available since LibreOffice 3.5.

#### Składnia

CSCH(Liczba)

Zwraca hiperboliczny cosecans z Liczby.

#### Przykład

=CSCH(1) zwraca w przybliżeniu 0.8509181282, hiperboliczny cosecans z 1.

## CZ.CAŁK.DZIELENIA

Zwraca część całkowitą z dzielenia.

#### Składnia

CZ.CAŁK.DZIELENIA(licznik; mianownik)

Zwraca część całkowitą z dzielenia dzielnej przez dzielnik.

QUOTIENT is equivalent to INT(numerator/denominator) for same-sign numerator and denominator, except that it may report errors with different error codes. More generally, it is equivalent to INT(numerator/denominator/SIGN(numerator/denominator))*SIGN(numerator/denominator).

#### Przykład

=CZ.CAŁK.DZIELENIA(11;3) zwraca wartość 3. Reszta 2 jest pomijana.

## EUROCONVERT

Funkcja umożliwia konwersję walut europejskich na i z euro.

#### Składnia

EUROCONVERT(Value; "From_currency"; "To_currency" [; full_precision [; triangulation_precision]])

Wartość jest wartością waluty, która ma zostać przekonwertowana.

Waluta_źródłowa i Waluta_docelowa to jednostki waluty, z których i na które będzie wykonywana konwersja. Musi to być oficjalny skrót danej waluty (np. "EUR"). Stawki (za jedno euro) zostały ustalone przez Komisję Europejską.

Pełna_dokładność jest parametrem opcjonalnym. Jeśli parametr ten zostanie pominięty lub ustawiony jako Fałsz, wynik zostanie zaokrąglony zgodnie z liczbami dziesiętnymi waluty docelowej. Jeśli opcja Pełna_dokładność jest ustawiona jako Prawda, wynik nie zostanie zaokrąglony.

Dokładność_triangulacji jest parametrem opcjonalnym. Jeśli została podana opcja Dokładność_triangulacji i ma wartość wyższą lub równą 3, wynik pośredni konwersji z wykorzystaniem waluty pośredniej (waluta1,EUR,waluta2) zostanie zaokrąglony zgodnie z podaną dokładnością. Pominięcie tego parametru powoduje, że wartość pośrednia nie będzie zaokrąglana. Jeśli walutą docelową jest EUR, parametr Dokładność_triangulacji jest używany, jeśli została wykonana triangulacja i przeliczenie z EUR na EUR.

### Przykłady:

=EUROCONVERT(100;"ATS";"EUR") konwertuje 100 szylingów austriackich na euro.

=EUROCONVERT(100;"EUR";"DEM") konwertuje 100 marek niemieckich na euro.

## EXP

Returns e raised to the power of a number. The constant e has a value of approximately 2.71828182845904.

#### Składnia

EXP(Liczba)

Liczba jest potęgą, do której ma zostać podniesiona liczba e.

#### Przykład

=EXP(1) returns 2.71828182845904, the mathematical constant e to Calc's accuracy.

## ILOCZYN

Mnoży wszystkie liczby podane w argumencie i zwraca iloczyn.

#### Składnia

PRODUCT(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1, Number 2, … , Number 255 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Przykład

=ILOCZYN(2;3;4) zwraca wartość 24.

## KOMBINACJE

Zwraca liczbę kombinacji podanej liczby elementów bez powtórzeń.

#### Składnia

KOMBINACJE(ilość 1; ilość 2)

Liczba_1 jest liczbą wszystkich elementów w zbiorze.

Liczba_2 jest liczbą wybranych elementów zbioru.

KOMBINACJE zwraca liczbę uporządkowanych sposobów wybrania danych elementów. Przykładowo, jeśli w zestawie są 3 elementy, A, B i C, 2 elementy można wybrać na 3 sposoby, tzn. AB, AC i BC.

Funkcja KOMBINACJE działa według formuły: liczba_1!/(liczba_2!*(liczba_1-liczba_2)!)

#### Przykład

=KOMBINACJE(3;2) zwraca wartość 3.

## KOMBINACJE.A

Zwraca liczbę kombinacji w podzestawie elementów, wliczając w to powtórzenia.

#### Składnia

KOMBINACJE.A(ilość 1; ilość 2)

Liczba_1 jest liczbą wszystkich elementów w zbiorze.

Liczba_2 jest liczbą wybranych elementów zbioru.

KOMBINACJE.A zwraca liczbę unikalnych sposobów wyboru elementów, dla których kolejność wyboru nie ma znaczenia i dopuszczalne są powtórzenia. Jeśli w zestawie są przykładowo 3 elementy: A, B i C, 2 elementy można wybrać na 6 sposobów, tzn. AA, AB, AC, BB, BC i CC.

KOMBINACJE.A korzysta ze wzoru: (liczba1 + liczba2 - 1)! / (liczba2! (liczba1 - 1)!)

#### Przykład

=KOMBINACJE.A(3;2) zwraca wartość 6.

## KONWERTUJ_OOO

Konwertuje wartość z jednego systemu liczbowego na inny. Współczynniki konwersji są podane w konfiguracji w postaci listy.

W poprzednich wersjach lista współczynników konwersji obejmowała nieistniejące już waluty europejskie oraz euro (co przedstawiają poniższe przykłady). Do konwersji walut zalecamy obecnie używanie funkcji EUROCONVERT.

#### Składnia

CONVERT_OOO(value; "text"; "text")

#### Przykład

=KONWERTUJ_OOO(100;"ATS";"EUR") zwraca wartość w euro dla 100 szylingów austriackich.

=KONWERTUJ_OOO(100;"EUR";"DEM") konwertuje 100 marek niemieckich na euro.

## LICZBA.CAŁK

Obcina liczbę poprzez usunięcie miejsc po przecinku.

#### Składnia

LICZBA.CAŁK(Liczba; Liczba cyfr)

Zwraca Liczba z zadaną Liczba cyfr miejsc po przecinku. Nadmiar miejsc po przecinku zostanie usunięta, niezależnie od znaku.

LICZBA.CAŁK(liczba; 0) zachowuje się jak funkcja ZAOKR.DO.CAŁK(liczba) dla liczb większych od zera, ale dla liczb mniejszych od zera zaokrągla w stronę zera.

Liczba widocznych miejsc po przecinku wyniku jest określona w menu LibreOffice – Preferencje Narzędzia – Opcje – LibreOffice Calc – Oblicz.

#### Przykład

=LICZBA.CAŁK(1,239;2) zwraca wartość 1,23. Cyfra 9 jest pomijana.

=LICZBA.CAŁK(-1,234999;3) zwraca wartość -1,234. Wszystkie 9 są pomijane.

## LN

Zwraca logarytm naturalny o podstawie e (2,71828182845904) dla podanej liczby.

#### Składnia

LN(Liczba)

Liczba jest wartością, z której należy obliczyć logarytm naturalny.

#### Przykład

=LN(3) zwraca logarytm naturalny o podstawie e z liczby 3 (ok. 1,0986).

=LN(EXP(321)) zwraca wartość 321.

## LOG

Zwraca logarytm o określonej podstawie z podanej liczby.

#### Składnia

LOG(Number [; Base])

Liczba jest wartością, z której należy obliczyć logarytm.

Podstawa (parametr opcjonalny) jest podstawą obliczanego logarytmu. Jeśli wartość ta zostanie pominięta, przyjęta zostanie podstawa 10.

#### Przykład

=LOG(10;3) zwraca logarytm o podstawie 3 z liczby 10 (ok. 2,0959).

=LOG(7^4;7) zwraca wartość 4.

## LOG10

Zwraca logarytm dziesiętny podanej liczby.

#### Składnia

LOG10(Liczba)

Zwraca logarytm dziesiętny liczby.

#### Przykład

=LOG10(5) zwraca ok. 0,69897 (logarytm dziesiętny z liczby 5).

## LOS

Zwraca liczbę losową z zakresu od 0 do 1.

This function is always recalculated whenever a recalculation occurs.

#### Składnia

LOS()

Funkcja ta generuje nową liczbę losową za każdym razem, gdy arkusz Calc dokonuje ponownego obliczenia. Aby ręcznie wymusić ponowne wykonanie obliczeń przez arkusz Calc, naciśnij klawisze F9.

To generate random numbers which never recalculate, either:

- Copy cells each containing =RAND(), and use Edit - Paste Special (with Paste All and Formulas not marked and Numbers marked).

- Use the Fill Cell command with random numbers (Sheet - Fill Cells - Fill Random Numbers).

- Use the RAND.NV() function for non-volatile random numbers.

#### Przykład

=LOS() zwraca liczbę losową z zakresu od 0 do 1.

## RAND.NV

Returns a non-volatile random number between 0 and 1.

This function is available since LibreOffice 7.0.

#### Składnia

RAND.NV()

This function produces a non-volatile random number on input. A non-volatile function is not recalculated at new input events. The function does not recalculate when pressing F9, except when the cursor is on the cell containing the function. The function is recalculated when opening the file.

#### Przykład

=RAND.NV() returns a non-volatile random number between 0 and 1.

## LOS.ZAKR

Zwraca liczbę losową ze zdefiniowanego zakresu.

This function is always recalculated whenever a recalculation occurs.

#### Składnia

LOS.ZAKR(dolna granica; górna granica)

Zwraca losową liczbę całkowitą z zakresu od dolnej i górnej (włącznie).

Funkcja ta generuje nową liczbę losową za każdym razem, gdy arkusz Calc dokonuje ponownego obliczenia. Aby ręcznie wymusić ponowne wykonanie obliczeń przez arkusz Calc, naciśnij klawisze F9.

Aby wygenerować liczby losowe, które nigdy nie są przeliczane, skopiuj komórki z tą funkcją i zastosuj funkcje Edycja – Wklej specjalnie... (Wklej wszystko przy niezaznaczonych formułach i zaznaczonych liczbach).

#### Przykład

=LOS.ZAKR(20;30) zwraca całkowitą liczbę losową z przedziału od 20 do 30.

## RANDBETWEEN.NV

Returns an non-volatile integer random number in a specified range.

This function is available since LibreOffice 7.0.

#### Składnia

RANDBETWEEN.NV(Bottom; Top)

Returns an non-volatile integer random number between integers Bottom and Top (both inclusive). A non-volatile function is not recalculated at new input events or pressing F9. However, the function is recalculated when pressing F9 with the cursor on the cell containing the function, when opening the file, and when Top or Bottom are recalculated.

#### Przykład

=RANDBETWEEN.NV(20;30) returns a non-volatile integer between 20 and 30.

=RANDBETWEEN.NV(A1;30) returns a non-volatile integer between the value of cell A1 and 30. The function is recalculated when the contents of cell A1 change.

## MOD

Zwraca resztę z dzielenia liczby przez dany podzielnik.

#### Składnia

MOD(dzielna; dzielnik)

Dla całkowitych argumentów ta funkcja zwraca Dzielną modulo Dzielnik, tzn. resztę z dzielenia Dzielnej przez Dzielnik.

Ta funkcja została zaimplementowana jako Dzielna - Dzielnik * ZAOKR.DO.CAŁK(Dzielna / Dzielnik).

#### Przykład

=MOD(22;3) zwraca wartość 1, resztę z dzielenia 22 przez 3.

=MOD(11,25;2,5) zwraca wartość 1,25.

## MODUŁ.LICZBY

Zwraca wartość bezwzględną liczby.

#### Składnia

MODUŁ.LICZBY(Liczba)

Liczba to liczba, której wartość bezwzględna ma być obliczona. Wartość bezwzględna to wartość liczby bez znaku +/-.

#### Przykład

=MODUŁ.LICZBY(-56) zwraca wartość 56.

=MODUŁ.LICZBY(12) zwraca wartość 12.

=MODUŁ.LICZBY(0) zwraca wartość 0.

## NAJMN.WSP.WIEL

Zwraca najmniejszą wspólną wielokrotność dwóch lub więcej liczb całkowitych.

#### Składnia

LCM(Integer 1 [; Integer 2 [; … [; Integer 255]]])

Integer 1, Integer 2, … , Integer 255 are integers, references to cells or to cell ranges of integers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Przykład

If you enter the numbers 512; 1024 and 2000 as Integer 1;2 and 3, then 128000 will be returned.

## NAJMN.WSP.WIEL_EXCEL2003

Wynikiem jest najmniejsza wspólna wielokrotność listy liczb.

Funkcje, których nazwy kończą się na .DODATKOWE lub .EXCEL2003, zwracają te same wartości, co odpowiadające im funkcje programu Microsoft Excel. Aby uzyskać wyniki oparte na standardach międzynarodowych, należy użyć funkcji o nazwie bez przyrostka,

#### Składnia

LCM_EXCEL2003(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1, Number 2, … , Number 255 are numbers, references to cells or to cell ranges of numbers.

#### Przykład

=NAJMN.WSP.WIEL_EXCEL2003(5;15;25) zwraca wartość 75.

## NAJW.WSP.DZIEL

Zwraca największy wspólny dzielnik dwóch lub więcej liczb całkowitych.

Największy wspólny dzielnik jest największą dodatnią liczbą całkowitą, która dzieli bez reszty każdą z podanych liczb całkowitych.

#### Składnia

GCD(Integer 1 [; Integer 2 [; … [; Integer 255]]])

Integer 1, Integer 2, … , Integer 255 are integers, references to cells or to cell ranges of integers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Przykład

=NAJW.WSP.DZIEL(16;32;24) zwraca wynik 8, ponieważ jest to największy wspólny dzielnik liczb podanych w wywołaniu funkcji.

=NAJW.WSP.DZIEL(B1:B3), gdzie komórki B1, B2, B3 zawierają wartości 9, 12, 9 daje w wyniku 3.

## NAJW.WSP.DZIEL_EXCEL2003

Wynikiem jest największy wspólny dzielnik listy liczb.

Funkcje, których nazwy kończą się na .DODATKOWE lub .EXCEL2003, zwracają te same wartości, co odpowiadające im funkcje programu Microsoft Excel. Aby uzyskać wyniki oparte na standardach międzynarodowych, należy użyć funkcji o nazwie bez przyrostka,

#### Składnia

GCD_EXCEL2003(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1, Number 2, … , Number 255 are numbers, references to cells or to cell ranges of numbers.

#### Przykład

=NAJW.WSP.DZIEL_EXCEL2003(5;15;25) zwraca wartość 5.

## PI

Zwraca 3,14159265358979, jako wartość stałej matematycznej PI z dokładnością do 14 miejsc po przecinku.

#### Składnia

PI()

#### Przykład

=PI() zwraca wartość 3,14159265358979.

## PIERW.PI

Zwraca wartość pierwiastka kwadratowego z liczby pomnożonej razy liczbę Pi.

#### Składnia

PIERW.PI(liczba)

Zwraca dodatni pierwiastek kwadratowy wartości (PI pomnożone przez liczbę).

Jest to ekwiwalent funkcji PIERWIASTEK(PI()*liczba).

#### Przykład

=PIERW.PI(2) zwraca pierwiastek z (2*Pi), czyli ok. 2,506628.

## PIERWIASTEK

Zwraca dodatni pierwiastek kwadratowy z liczby.

#### Składnia

PIERWIASTEK(liczba)

Zwraca dodatni pierwiastek kwadratowy z liczba.

Liczba musi być dodatnia.

#### Przykład

=PIERWIASTEK(16) zwraca wartość 4.

=PIERWIASTEK(-16) zwraca błąd nieprawidłowy argument.

## POTĘGA

Zwraca potęgę podanej liczby.

#### Składnia

POTĘGA(podstawa; wykładnik)

Zwraca podstawę podniesioną do potęgi równej wykładnikowi.

Ten sam wynik można osiągnąć poprzez zastosowanie operatora potęgowania ^:

Podstawa^wykładnik

=POWER(0,0) returns 1.

#### Przykład

=POTĘGA(4;3) zwraca wartość 64, tzn. 4 podniesione do potęgi 3.

4^3 również zwraca 4 do potęgi 3.

## RADIANY

Konwertuje stopnie na radiany

#### Składnia

RADIANY(Liczba)

Liczba jest kątem w stopniach, który ma zostać zamieniony na radiany.

#### Przykład

=RADIANY(90) zwraca wartość 1,5707963267949, co stanowi wartość PI/2 z dokładnością programu Calc.

## SEC

Zwraca secans podanego kąta (w radianach).Secans równy jest 1 dzielone przez cosinus podanego kąta

This function is available since LibreOffice 3.5.

#### Składnia

SEC(Liczba)

Zwraca (trygonometryczny) sekans z Liczby, kąt w radianach.

Aby uzyskać sekans kąta w stopniach, zastosuj funkcję RADIANY.

#### Przykład

=SEC(PI()/4) zwraca w przybliżeniu 1.4142135624, odwrotność kosinusa z PI/4 radianów.

=SEC(RADIANY(60)) zwraca 2, sekans z 60 stopni.

## SECH

Zwraca hiperboliczny sekans z liczby

This function is available since LibreOffice 3.5.

#### Składnia

SECH(Liczba)

Zwraca hiperboliczny sekans z Liczby.

#### Przykład

=SECH(0) zwraca 1, hiperboliczny sekans z 0.

## SILNIA

Zwraca silnię liczby.

#### Składnia

SILNIA(Liczba)

Zwraca Liczba!, silnię z Liczba, obliczonej jako 1*2*3*4* ... * Liczba.

=SILNIA(0) z definicji wynosi 1.

Silnia liczby ujemnej zwraca błąd "nieprawidłowy argument".

#### Przykład

=SILNIA(3) wynosi 6.

=SILNIA(0) wynosi 1.

## SIN

Zwraca sinus podanej liczby (kąta).

#### Składnia

SIN(Liczba)

Zwraca sinus liczby (kąta w radianach).

Aby uzyskać sinus kąta w stopniach, zastosuj funkcję RADIANY.

#### Przykład

=SIN(PI()/2) zwraca 1 ― sinus kąta o mierze PI/2 radianów.

=SIN(RADIANY(30)) zwraca wartość 0,5, czyli sinus kąta 30 stopni.

## SINH

Zwraca sinus hiperboliczny liczby.

#### Składnia

SINH(liczba)

Zwraca sinus hiperbolicznyliczby.

#### Przykład

=SINH(0) zwraca wartość 0, sinus hiperboliczny dla 0.

## STOPNIE

Konwertuje radiany na stopnie.

#### Składnia

STOPNIE(liczba)

Liczba to kąt wyrażony w radianach, który ma być przeliczony na stopnie.

#### Przykład

=STOPNIE(PI()) zwraca wartość 180 stopni.

## SUM

Adds a set of numbers.

#### Składnia

SUM(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1, Number 2, … , Number 255 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Przykład

Jeśli wpiszesz liczby 2; 3 i 4 w liczbę 1; 2 i 3 pola tekstowego, 9 zostanie zwrócona jako wynik.

=SUMA(A1;A3;B5) oblicza sumę tych trzech komórek. =SUMA(A1:E10) oblicza sumę wszystkich komórek z zakresu od A1 do E10.

Wraz z funkcją SUMA() można używać warunków łączonych operatorem logicznym I w następujący sposób:

Założenie przykładowe: Do tabeli wprowadzane są faktury. Kolumna A zawiera datę zamówienia, kolumna B zawiera kwotę. Należy przygotować formułę zwracającą sumę wszystkich faktur tylko dla określonego miesiąca, na przykład wartość faktur tylko dla okresu >=01.01.2008 do <01.02.2008. Zakres wartości dat obejmuje komórki A1:A40, zakres wartości do zsumowania obejmuje komórki B1:B40. Komórka C1 zawiera datę początkową (01.01.2008) uwzględnianą w obliczeniach, natomiast komórka C2 zawiera datę końcową (01.02.2008) nie uwzględnianą w obliczeniach.

Wprowadź następującą formułę macierzową:

=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Aby wyrażenie to wprowadzić w postaci formuły macierzowej, przy zamykaniu formuły zamiast nacisnąć klawisz Enter, należy nacisnąć klawisze Shift + Command + Ctrl + Enter. Formuła zostanie wówczas wyświetlona na pasku Formuła w nawiasach.

{=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Formuła wykorzystuje fakt, że wynik porównania wynosi 1 w przypadku spełnienia kryteriów i 0 w przeciwnym wypadku. Wyniki indywidualnych porównań są traktowane jako macierz wartości i używane w mnożeniu macierzowym, a następnie te wartości są sumowane w celu uzyskania wyniku macierzowego.

## SUMA.KWADRATÓW

Calculates the sum of the squares of a set of numbers.

#### Składnia

SUMSQ(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1, Number 2, … , Number 255 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Przykład

If you enter the numbers 2; 3 and 4 in the Number 1; 2 and 3 arguments, 29 is returned as the result.

## SUMA.SZER.POT

Zwraca sumę potęg liczby.

SERIESSUM(x;n;m;c) = c1xn + c2xn+m + c3xn+2m + ... + cixn + (i-1)m.

#### Składnia

SUMA.SZER.POT(x; n; m; współczynniki)

X to liczba będąca zmienną niezależną.

n: potęga początkowa

M to przyrost wartości N

Współczynniki są serią współczynników. Dla każdego współczynnika suma serii jest rozszerzana o jedną sekcję.

## SUMIF

Adds the cells specified by a given criterion. This function is used to sum a range when you search for a certain value.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Składnia

SUMIF(Range; Criterion [; SumRange])

Range is the range to which the criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

- A Number or Logical value. A matching cell content equals the Number or Logical value.

- A value beginning with a comparator (<, <=, =, >, >=, <>).

  For =, if the value is empty it matches empty cells.

  For <>, if the value is empty it matches non-empty cells.

  For <>, if the value is not empty it matches any cell content except the value, including empty cells.

  Note: "=0" does not match empty cells.

  For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

- Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Zakres_sumowania to zakres wartości, które mają być zsumowane. Jeśli ten parametr nie został określony, zostaną zsumowane wartości odnalezione w zakresie.

SUMIF supports the reference concatenation operator (~) only in the Criterion parameter, and only if the optional SumRange parameter is not given.

#### Przykład

Przykład sumowania jedynie ujemnych liczb: =SUMA.JEŻELI(A1:A10;"<0")

=SUMIF(A1:A10;">0";B1:B10) - sums values from the range B1:B10 only if the corresponding values in the range A1:A10 are >0.

Aby zapoznać się z innymi przykładami składni, które mogą być wykorzystywane z funkcją SUMA.JEŻELI(), patrz funkcja LICZ.JEŻELI().

## SUMY.CZĘŚCIOWE

Oblicza sumy pośrednie. Jeśli zakres już zawiera sumy pośrednie, nie są one uwzględniane w dalszych obliczeniach. Ta funkcja użyta wraz z autofiltrami pozwala uwzględnić w obliczeniach tylko filtrowane rekordy.

#### Składnia

SUMY.CZĘŚCIOWE(funkcja; zakres)

Funkcja jest liczbą oznaczającą jedną z następujących funkcji:

Indeks funkcji (zawiera ukryte wartości) | Indeks funkcji (ignoruje ukryte wartości) | Funkcja
1 | 101 | ŚREDNIA
2 | 102 | ILE.LICZB
3 | 103 | ILE.NIEPUSTYCH
4 | 104 | MAKS
5 | 105 | MIN
6 | 106 | ILOCZYN
7 | 107 | ODCH.STANDARDOWE
8 | 108 | ODCH.STANDARD.POPUL
9 | 109 | SUMA
10 | 110 | WARIANCJA
11 | 111 | WARIANCJA.POPUL

Użyj numerów 1-11, aby uwzględnić ręcznie ukryte wiersze lub 101-111, aby je wykluczyć; Odfiltrowane komórki są zawsze wykluczone.

Zakres jest zakresem uwzględnianych komórek.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Przykład

Masz taberlę w zakresie komórek A1: B6 zawierającą zestawienie materiałów dla 10 uczniów. Rząd 2 (pióro) jest ręcznie ukryty. Chcesz zobaczyć sumę wyświetlanych liczb; to jest tylko podsuma dla filtrowanych wierszy. W tym przypadku prawidłową formułą będzie:

| A | B
1 | PRZEDMIOT | ILOŚĆ
2 | Pióro | 10
3 | Ołówek | 10
4 | Notebook | 10
5 | Gumka | 10
6 | Temperówka | 10

=SUMY.CZĘŚCIOWE(9; B2:B6) zwraca 50

=SUMY.CZĘŚCIOWE(109; B2:B6) zwraca 40

## TAN

Zwraca tangens podanego kąta.

#### Składnia

TAN(liczba)

Zwraca tangens (trygonometryczny) z Liczba, kąta wyrażonego w radianach.

Aby uzyskać tangens kąta w stopniach, zastosuj funkcję RADIANY.

#### Przykład

=TAN(PI()/4) zwraca wartość 1, tangens kąta o mierze PI/4 radianów.

=TAN(RADIANY(45)) zwraca wartość 1, czyli tangens kąta 45 stopni.

## TANH

Zwraca tangens hiperboliczny liczby.

#### Składnia

TANH(liczba)

Zwraca tangens hiperboliczny z liczby.

#### Przykład

=TANH(0) zwraca wartość 0, tangens hiperboliczny wartości 0.

## WIELOMIAN

Zwraca silnię sum argumentów podzieloną przez iloczyn silni argumentów.

#### Składnia

MULTINOMIAL(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1, Number 2, … , Number 255 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Przykład

=WIELOMIAN(F11:H11) zwraca wartość 1260, jeżeli komórki od F11 do H11 zawierają wartości 2, 3 i 4. Funkcja odpowiada formule =(2+3+4)! / (2!*3!*4!)

## ZAOKR

Zwraca liczbę zaokrągloną do pewnej liczby miejsc dziesiętnych.

#### Składnia

ROUND(Number [; Count])

Zwraca Liczbę zaokrągloną do tylu miejsc dziesiętnych, ile wynosi argument Ilość. Jeśli Ilość jest pominięta lub wynosi zero, to funkcja zaokrągla do najbliższej liczby całkowitej. Jeśli Ilość jest mniejsza od zera, to funkcja zaokrągla do najbliższych 10, 100, 1000, itd.

Funkcja zaokrągla wartość do najbliższej liczby. Patrz też ZAOKR.DÓŁ i ZAOKR.GÓRA.

#### Przykład

=ZAOKR(2,348;2) zwraca wartość 2,35

=ZAOKR(-32,4834;3) zwraca wartość -32,483. Aby wyświetlić wszystkie pozycje dziesiętne, należy zmienić format komórki.

=ZAOKR(2,348;0) zwraca wartość 2.

=ZAOKR(2,5) zwraca wartość 3.

=ZAOKR(987,65;-2) zwraca wartość 1000.

## ZAOKR.DO.CAŁK

Zaokrągla liczbę w dół do najbliższej liczby całkowitej.

#### Składnia

ZAOKR.DO.CAŁK(Liczba)

Zwraca Liczbę zaokrągloną w dół do najbliższej liczby całkowitej.

Liczby ujemne są zaokrąglane do mniejszej liczby całkowitej.

#### Przykład

=ZAOKR.DO.CAŁK(5,7) zwraca wartość 5.

=ZAOKR.DO.CAŁK(-1,3) zwraca wartość -2.

## ZAOKR.DO.NPARZ

Zwraca liczbę zaokrągloną w górę do następnej liczby nieparzystej.

#### Składnia

ZAOKR.DO.NPARZ(liczba)

Liczba jest liczbą, która ma zostać zaokrąglona w kierunku od zera.

#### Przykład

=ZAOKR.DO.NPARZ(1,2) zwraca wartość 3.

=ZAOKR.DO.NPARZ(1) zwraca wartość 1.

=ZAOKR.DO.NPARZ(0) zwraca wartość 1.

=ZAOKR.DO.NPARZ(-3,1) zwraca wartość -5.

## ZAOKR.DO.PARZ

Zwraca liczbę zaokrągloną w górę do następnej liczby parzystej.

#### Składnia

ZAOKR.DO.PARZ(Liczba)

Liczba jest liczbą, która ma zostać zaokrąglona w górę do następnej liczby parzystej.

#### Przykład

=ZAOKR.DO.PARZ(2,3) zwraca wartość 4.

=ZAOKR.DO.PARZ(2) zwraca wartość 2.

=ZAOKR.DO.PARZ(0) zwraca wartość 0.

=ZAOKR.DO.PARZ(-0,5) zwraca wartość -2.

## ZAOKR.DO.WIELOKR

Wynikiem jest liczba zaokrąglona do najbliższej całkowitej wielokrotności drugiej liczby.

#### Składnia

ZAOKR.DO.WIELOKR(liczba; wielokrotność)

Zwraca liczbę po zaokrągleniu do najbliższej wielokrotności.

Alternatywnie można zastosować funkcję Wielokrotność * ZAOKR(liczba/wielokrotność).

#### Przykład

=ZAOKR.DO.WIELOKR(15,5;3) zwraca wartość 15, bo liczbie 15,5 jest bliżej do 15 (= 3*5) niż do 18 (= 3*6).

=ZAOKR.DO.WIELOKR(1,4;0,5) zwraca wartość 1,5 (=0,5*3).

## ZAOKR.DÓŁ

Zaokrągla liczbę w dół.

#### Składnia

ROUNDDOWN(Number [; Count])

Zwraca Liczba zaokrągloną w dół (w kierunku zera) do Ilość miejsc po przecinku. Jeśli Ilość jest pominięty lub zero, funkcja zaokrągla w dół do najbliższej liczby całkowitej. Jeśli Ilość jest ujemna, funkcja zaokrągla w dół do najbliższej 10, 100, 1000, itd.

Ta funkcja zaokrągla liczbę w dół. Patrz też ZAOKR.GÓRA i ZAOKR.

#### Przykład

=ZAOKR.DÓŁ(1,234;2) zwraca wartość 1,23.

=ZAOKR.DÓŁ(45,67;0) zwraca wartość 45.

=ZAOKR.DÓŁ(-45,67) zwraca wartość -45.

=ZAOKR.DÓŁ(987,65;-2) zwraca wartość 900.

## ZAOKR.GÓRA

Zaokrągla liczbę w górę, uwzględniając podaną liczbę miejsc po przecinku.

#### Składnia

ROUNDUP(Number [; Count])

Zwraca Liczba zaokrągloną w górę (od zera) do Ilość miejsc po przecinku. Jeśli Ilość jest pominięty lub zero, funkcja zaokrągla w górę do najbliższej liczby całkowitej. Jeśli Ilość jest ujemna, funkcja zaokrągla w górę do najbliższej 10, 100, 1000, itd.

Funkcja zaokrągla liczbę w górę. Patrz też ZAOKR.DÓŁ i ZAOKR.

#### Przykład

=ZAOKR.GÓRA(1,1111;2) zwraca wartość 1,12.

=ZAOKR.GÓRA(1,2345;1) zwraca wartość 1,3.

=ZAOKR.GÓRA(45,67;0) zwraca wartość 46.

=ZAOKR.GÓRA(-45,67) zwraca wartość -46.

=ZAOKR.GÓRA(987,65;-2) zwraca wartość 1000.

## ZNAK.LICZBY

Zwraca znak liczby. Funkcja zwraca wartość 1 dla znaku dodatniego i -1 dla znaku ujemnego. Jeśli liczba jest zerem, funkcja zwraca również zero.

#### Składnia

ZNAK.LICZBY(liczba)

Liczba jest liczbą, dla której należy określić znak.

#### Przykład

=ZNAK.LICZBY(3,4) zwraca wartość 1.

=ZNAK.LICZBY(-4,5) zwraca wartość -1.

Tematy pokrewne

Funkcje według kategorii