Contenu
Index 🔎︎

# ScriptForge. Service Array

Fournit une collection de méthodes pour manipuler et transformer des matrices d'une dimension (vecteurs) et des matrices de deux dimensions (matrices). Cela inclut les opérations d'ensemble, le tri, l'import et l'export à partir de fichiers texte.

Les matrices avec plus de deux dimensions ne peuvent pas être utilisées avec les méthodes de ce service, la seule exception étant la méthode CountDims qui accepte les matrices avec un nombre quelconque de dimensions.

Les éléments de matrice peuvent contenir n'importe quel type de valeur, y compris des (sous) matrices.

## Invocation du service

Avant de pouvoir utiliser le service Array, la bibliothèque ScriptForge doit être chargée en utilisant :

          GlobalScope.BasicLibraries.LoadLibrary("ScriptForge")

Charger la bibliothèque créera l'objet SF_Array qui peut être utilisé pour appeler les méthode dans le service Array.

Les extraits de code suivants montrent les différentes façons d'appeler des méthodes dans le service Array (la méthode Append est utilisée comme exemple) :

          SF_Array.Append(...)

          Dim arr    :    arr = SF_Array
          arr.Append(...)

          Dim arr    :    arr = CreateScriptService("Array")
          arr.Append(...)

La méthode CreateScriptService n'est disponible qu'après avoir chargé la bibliothèque ScriptForge.

Méthodes
Append AppendColumn AppendRow Contains ConvertToDictionary CountDims Difference ExportToTextFile ExtractColumn ExtractRow | Flatten ImportFromCSVFile IndexOf Insert InsertSorted Intersection Join2D Prepend PrependColumn PrependRow | RangeInit Reverse Shuffle Slice Sort SortColumns SortRows Transpose TrimArray Union Unique

Le premier argument de la plupart des méthodes est l'objet matrice à prendre en compte. Il est toujours passé par référence et laissé inchangé. Les méthodes telles que Append, Prepend, etc. renvoient un nouvel objet matrice après leur exécution.

## Append

Ajoute les éléments répertoriés comme arguments à la fin de la matrice d'entrée.

### Syntaxe :

          SF_Array.Append(Array_1D As Variant, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Paramètres :

Array_1D : la matrice préexistante, peut être vide.

arg0, ... : une liste d'éléments à ajouter à Array_1D.

### Exemple :

          Sub Example_Append()
          Dim a As Variant
              a = SF_Array.Append(Array(1, 2, 3), 4, 5)
                  ' (1, 2, 3, 4, 5)
          End Sub

## AppendColumn

Ajoute une nouvelle colonne sur le côté droit d'une matrice à deux dimensions. La matrice résultante a les mêmes limites inférieures que la matrice bidimensionnelle initiale.

### Syntaxe :

          SF_Array.AppendColumn(Array_2D As Variant, New_Column As Variant) As Variant

### Paramètres :

Array_2D: la matrice préexistante, peut être vide. Si cette matrice n'a qu'une seule dimension, elle est considérée comme la première colonne de la matrice bidimensionnelle résultante.

New_Column : une matrice à 1 dimension avec autant d'éléments qu'il y a de lignes dans Array_2D.

### Exemple :

          Sub Example_AppendColumn()
          Dim a As Variant, b As variant
              a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((1, 4), (2, 5), (3, 6))
              b = SF_Array.AppendColumn(a, Array(7, 8, 9))
                  ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
              c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
          End Sub

## AppendRow

Ajoutez une nouvelle ligne au bas d'une matrice à deux dimensions. La matrice résultante a les mêmes limites inférieures que la matrice initiale à deux dimensions.

### Syntaxe :

          SF_Array.AppendRow(Array_2D As Variant, Row As Variant) As Variant

### Paramètres :

Array_2D: la matrice préexistante, peut être vide. Si cette matrice a 1 dimension, elle est considérée comme la première ligne de la matrice à 2 dimensions résultante.

Row : une matrice 1D avec autant d'éléments qu'il y a de colonnes dans Array_2D.

### Exemple :

          Sub Example_AppendRow()
          Dim a As Variant, b As variant
              a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
                  '  ((1, 2, 3), (4, 5, 6))
              b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
          End Sub

## Contains

Vérifier si un tableau à une dimension contient un certain nombre, du texte ou une date. La comparaison de texte peut être sensible à la casse ou non.
Les matrices d'entrée triées doivent être remplies de manière homogène, ce qui signifie que tous les éléments doivent être des scalaires du même type (les éléments Empty et Null sont interdits).
Le résultat de la méthode est imprévisible lorsque la matrice est annoncée comme triée et ne l'est pas en réalité.
Une recherche binaire est effectuée lorsque la matrice est triée, sinon, elle est simplement parcourue de haut en bas et les éléments Empty et Null sont ignorés.

### Syntaxe :

          SF_Array.Contains(Array_1D, ToFind As Variant, [CaseSensitive As Boolean], [SortOrder As String]) As Boolean

### Paramètres :

Array_1D : la matrice à parcourir.

ToFind : un nombre, une date ou une chaîne à trouver.

CaseSensitive : uniquement pour une comparaison de chaînes, par défaut = False.

SortOrder : "ASC", "DESC" ou "" (= non trié, par défaut)

### Exemple :

          Sub Example_Contains()
          Dim a As Variant
              a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
              SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
          End Sub

## ConvertToDictionary

Stocker le contenu d'une matrice de deux colonnes dans un objet ScriptForge.Dictionary . Les clés seront extraites de la première colonne et les éléments de la seconde.

### Syntaxe :

          SF_Array.ConvertToDictionary(Array_2D As Variant) As Variant

### Paramètres :

Array_1D : la première colonne doit contenir exclusivement des chaînes dont la longueur est > 0, dans n'importe quel ordre.

### Exemple :

          Sub Example_ConvertToDictionary()
          Dim a As Variant, b As Variant
              a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
              b = SF_Array.ConvertToDictionary(a)
              MsgBox b.Item("c") ' 3
          End Sub

## CountDims

Compter le nombre de dimensions d'une matrice. Le résultat peut être supérieur à deux.
Si l'argument n'est pas une matrice, renvoie -1
Si la matrice n'est pas initialisée, renvoie 0.

### Syntaxe :

          SF_Array.CountDims(Array_ND As Variant) As Integer

### Paramètres :

Array_ND : la matrice à examiner.

### Exemple :

          Sub Example_CountDims()
          Dim a(1 To 10, -3 To 12, 5)
              MsgBox SF_Array.CountDims(a) ' 3
          End Sub

## Difference

Construisez un ensemble, dont la matrice est basée sur 0, en utilisant l'opérateur de différence sur les deux matrices d'entrée. Les éléments résultants viendront du premier tableau et non du second.
La matrice résultante est triée par ordre croissant.
Les deux matrices d'entrée doivent être remplies avec homogénéité, leurs éléments doivent être des scalaires de même type. Les valeurs Empty et Null ne sont pas permises.
La comparaison de texte peut être sensible à la casse ou non.

### Syntaxe :

          SF_Array.Difference(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Paramètres :

Array1_1D : une matrice de référence à 1 dimension, dont les éléments sont examinés pour suppression.

Array2_1D : une matrice de 1 dimension, dont les éléments sont soustraits de la première matrice saisie.

CaseSensitive : uniquement si les matrices sont peuplées avec des chaînes, par défaut = False.

### Exemple :

          Sub Example_Difference()
          Dim a As Variant
              a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("A", "B")
          End Sub

## ExportToTextFile

Écrivez tous les éléments du tableau de manière séquentielle dans un fichier texte. Si le fichier existe déjà, il sera écrasé sans avertissement.

### Syntaxe :

          SF_Array.ExportToTextFile(Array_1D As Variant, FileName As String, [Encoding As String]) As Boolean

### Paramètres :

Array_1D : la matrice à exporter. Elle ne doit contenir que des chaînes.

FileName : le nom du fichier texte contenant les données. Le nom est exprimé tel que donné par la propriété FileNaming du service SF_FileSystem. Par défaut = any (à la fois le format URL et le format système d'exploitation natif sont admis).

Encoding : le jeu de caractères qui doit être utilisé. Utilisez l'un des noms listés dans IANA character sets. Remarquez que LibreOffice peut ne pas implémenter tous les jeux de caractères existants. Par défaut, c'est "UTF-8".

### Exemple :

          Sub Example_ExportToTextFile()
              SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
          End Sub

## ExtractColumn

Extraire d'une matrice à deux dimensions une colonne spécifique en tant que nouvelle matrice.
Ses limites inférieures LBound et supérieures UBound sont identiques à celles de la première dimension de la matrice d'entrée.

### Syntaxe :

          SF_Array.ExtractColumn(Array_2D As Variant, ColumnIndex As Long) As Variant

### Paramètres :

Array_2D : La matrice à partir de laquelle extraire.

ColumnIndex : Le numéro de colonne à extraire - cela doit être l'intervalle [LBound, UBound].

### Exemple :

          Sub Example_ExtractColumn
             'Crée une matrice 3x3 : |1, 2, 3|
             '                      |4, 5, 6|
             '                      |7, 8, 9|
             Dim mat as Variant, col as Variant
             mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
             mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
             mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
             'Extrait la troisième colonne : |3, 6, 9|
             col = SF_Array.ExtractColumn(mat, 2)
          End Sub

## ExtractRow

Extraire d'une matrice à deux dimensions une ligne spécifique en tant que nouvelle matrice.
Ses limites inférieures LBound et supérieures UBound sont identiques à celles de la deuxième dimension de la matrice d'entrée.

### Syntaxe :

          SF_Array.ExtractRow(Array_2D As Variant, RowIndex As Long) As Variant

### Paramètres :

Array_2D : la matrice à partir de laquelle extraire.

RowIndex : le numéro de ligne à extraire - cela doit être dans l'intervalle [LBound, UBound].

### Exemple :

          Sub Example_ExtractRow
             'Crée une matrice 3x3 : |1, 2, 3|
             '                      |4, 5, 6|
             '                      |7, 8, 9|
             Dim mat as Variant, row as Variant
             mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
             mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
             mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
             'Extrait la première ligne : |1, 2, 3|
             row = SF_Array.ExtractRow(mat, 0)
          End Sub

## Flatten

Empilez tous les éléments individuels d'une matrice et tous les éléments de ses sous-matrices dans une nouvelle matrice sans sous-matrice. Les sous-matrices vides sont ignorées et les sous-matrices avec un nombre de dimensions supérieur à un ne sont pas aplaties.

### Syntaxe :

          SF_Array.Flatten(Array_1D As Variant) As Variant

### Paramètres :

Array_1D : la matrice pré-existante, elle peut être vide.

### Exemple :

          Sub Example_Flatten()
          Dim a As Variant
              a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
                  ' (1, 2, 3, 4, 5)
          End Sub

Vous pouvez utiliser la méthode Flatten en même temps que d'autres méthodes telles que Append ou Prepend pour concaténer un ensemble de matrices 1D en une seule matrice 1D.

### Exemple :

Vous trouverez ci-après un exemple de comment les méthodes Flatten et Append peuvent être combinées pour concaténer trois matrices.

          Sub Concatenate_Example
             'Crée trois matrices pour cet exemple
             Dim a as Variant, b as Variant, c as Variant
             a = Array(1, 2, 3)
             b = Array(4, 5)
             c = Array(6, 7, 8, 9)
             'Concatène les trois matrices en une seule matrice 1D
             Dim arr as Variant
             arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
             '(1, 2, 3, 4, 5, 6, 7, 8, 9)
          End Sub

## ImportFromCSVFile

Importez les données contenues dans un fichier dont les valeurs sont séparées par des virgules (CSV). Les virgules peuvent être remplacées par n'importe quel caractère.

Le format CSV applicable est décrit dans IETF Common Format and MIME Type for CSV Files.

Chaque ligne du fichier contient un enregistrement complet (séparer les lignes n'est pas autorisé).
Cependant, des séquences comme \n, \t, ... sont laissées inchangées. Utilisez la méthode SF_String.Unescape() pour les gérer.

La méthode renvoie une matrice à deux dimensions dont les lignes correspondent à un enregistrement unique lu dans un fichier dont les colonnes correspondent à un champ de l'enregistrement. Aucune vérification n'est faite quant à la cohérence des types de champs à travers les colonnes. Une meilleure estimation sera faite pour identifier les types numériques et de date.

Si une ligne contient plus ou moins de champs que la première ligne du fichier, une exception est levée. Cependant les lignes vides sont simplement ignorées. Si la taille du fichier excède le nombre de la limite d'éléments (voir à l'intérieur du code), un avertissement est levé et la matrice est tronquée.

### Syntaxe :

          SF_Array.ImportFromCSVFile(FileName As String, [Delimiter As String], [DateFormat As String]) As Variant

### Paramètres :

FileName : le nom du fichier texte contenant les données. Le nom est exprimé tel qu'il est donné par la propriété FileNaming actuelle du service SF_FileSystem. Par défaut = quelconque (le format URL et le format natif du système d'exploitation sont admis).

Delimiter : un seul caractère, généralement une virgule, un point-virgule ou un caractère TAB. Par défaut = ",".

DateFormat : un mécanisme spécial gère les dates lorsque DateFormat est soit "AAAA-MM-JJ", "JJ-MM-AAAA" ou "MM-JJ-AAAA". Le tiret (-) peut être remplacé par un point (.), une barre oblique (/) ou un espace. Les autres formats de date seront ignorés. Les dates par défaut "" sont considérées comme du texte normal.

### Exemple :

Étant donné ce fichier CSV :

          Name,DateOfBirth,Address,City
          Anna,2002/03/31,"Rue de l'église, 21",Toulouse
          Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne

          Sub Example_ImportFromCSVFile()
          Dim a As Variant
              a = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
              MsgBox a(0, 3)    ' City
              MsgBox TypeName(a(1, 2))    ' Date
              MsgBox a(2, 2)    ' Rue Albert Einstein, 113A
          End Sub

## IndexOf

Rechercher dans une matrice à une dimension un nombre, une chaîne ou une date. La comparaison de texte peut être sensible ou non à la casse.
Si la matrice est triée, elle doit être remplie de manière homogène, ce qui signifie que tous les éléments doivent être des scalaires du même type (les éléments Empty et Null sont interdits).
Le résultat de la méthode est imprévisible lorsque la matrice est annoncée comme triée et ne l'est pas en réalité.
Une recherche binaire est effectuée sur des matrices triées. Sinon, les matrices sont simplement analysées de haut en bas et les éléments Empty et Null sont ignorés.
La méthode renvoie LBound(input array) - 1 si la recherche n'a pas abouti.

### Syntaxe :

          SF_Array.IndexOf(Array_1D, ToFind As Variant, [CaseSensitive As Boolean], [SortOrder As String]) As Long

### Paramètres :

Array_1D : la matrice à scanner.

ToFind : un nombre, une date ou une chaîne à trouver.

CaseSensitive : uniquement pour une comparaison de chaînes, par défaut = False.

SortOrder : "ASC", "DESC" ou "" (= non trié, par défaut)

### Exemple :

          Sub Example_IndexOf()
              MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
              MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
          End Sub

## Insert

Insérez avant un index donné de la matrice d'entrée, les éléments répertoriés comme arguments.
Les arguments sont insérés à l'aveugle. Chacun d'eux peut être soit un scalaire de n'importe quel type, soit une sous-matrice.

### Syntaxe :

          SF_Array.Insert(Array_1D As Variant, Before As Long, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Paramètres :

Array_1D : la matrice préexistante, peut être vide.

Before : l'index avant lequel insérer ; doit être dans l'intervalle [LBound, UBound + 1].

arg0, ... : une liste d'éléments à insérer dans Array_1D.

### Exemple :

          Sub Example_Insert()
          Dim a As Variant
              a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
                  ' (1, 2, "a", "b", 3)
          End Sub

## InsertSorted

Insérer dans une matrice triée un nouvel élément à sa place.
La matrice doit être remplie de manière homogène, ce qui signifie que tous les éléments doivent être des scalaires du même type. Les éléments
Empty et Null sont interdits.

### Syntaxe :

          SF_Array.InsertSorted(Array_1D As Variant, Item As Variant, SortOrder As String, CaseSensitive As Boolean) As Variant

### Paramètres :

Array_1D : la matrice à trier.

Item : la valeur scalaire à insérer, du même type que les éléments de la matrice existants.

SortOrder : "ASC" (par défaut) ou "DESC".

CaseSensitive : uniquement pour une comparaison de chaînes, par défaut = False.

### Exemple :

          Sub Example_InsertSorted()
          Dim a As Variant
              a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
                  ' ("A", "B", "C", "a", "b")
          End Sub

## Intersection

Construire un ensemble, en tant que matrice de base zéro, en appliquant l'opérateur d'ensemble d'intersection sur les deux matrices d'entrée. Les éléments résultants sont contenus dans les deux matrices.
La matrice résultante est triée par ordre croissant.
Les deux matrices d'entrée doivent être remplies de manière homogène, c'est-à-dire que tous les éléments doivent être des scalaires du même type. Les éléments Empty et Null sont interdits.
La comparaison de texte peut être sensible ou non à la casse.

### Syntaxe :

          SF_Array.Intersection(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Paramètres :

Array1_1D : la première matrice de saisie.

Array2_1D : la seconde matrice de saisie.

CaseSensitive : s'applique aux matrices peuplées avec des éléments de texte, par défaut = False.

### Exemple :

          Sub Example_Intersection()
          Dim a As Variant
              a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("C", "b")
          End Sub

## Join2D

Joindre une matrice à deux dimensions avec deux délimiteurs, un pour les colonnes, un pour les lignes.

### Syntaxe :

          SF_Array.Join2D(Array_2D As Variant, ColumnDelimiter As String, RowDelimiter As String, Quote As Boolean) As String

### Paramètres :

Array_2D : chaque élément doit être soit du texte, un nombre, une date ou un booléen.
Les dates sont transformées au format AAAA-MM-JJ hh:mm:ss.
Les éléments invalides sont remplacés par une chaîne de longueur nulle.

ColumnDelimiter : délimite chaque colonne (par défaut = Tab/Chr(9)).

RowDelimiter: délimite chaque ligne (par défaut = LineFeed/Chr(10))

Quote : si True, protège les chaînes avec des guillemets doubles. La valeur par défaut est False.

### Exemple :

          Sub Example_Join2D()
          -                     | 1, 2, "A", [2020-02-29], 5      |
          -    SF_Array.Join_2D(| 6, 7, "this is a string", 9, 10 |, ",", "/")
          -            ' "1,2,A,2020-02-29 00:00:00,5/6,7,this is a string,9,10"
          End Sub

## Prepend

Ajouter au début de la matrice d'entrée les éléments répertoriés comme arguments.

### Syntaxe :

          SF_Array.Prepend(Array_1D As Variant, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Paramètres :

Array_1D : la matrice préexistante, peut être vide.

arg0, ... : une liste d'éléments à ajouter à Array_1D.

### Exemple :

          Sub Example_Prepend()
          Dim a As Variant
              a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
                  ' (4, 5, 1, 2, 3)
          End Sub

## PrependColumn

Ajouter au côté gauche d'une matrice à deux dimensions une nouvelle colonne. La matrice résultante a les mêmes limites inférieures que la matrice initiale à deux dimensions.

### Syntaxe :

          SF_Array.PrependColumn(Array_2D As Variant, Column As Variant) As Variant

### Paramètres :

Array_2D: la matrice préexistante, peut être vide. Si cette matrice a 1 dimension, elle est considérée comme la dernière colonne de la matrice à 2 dimensions résultante.

Column : une matrice à 1 dimension avec autant d'éléments qu'il y a de lignes dans Array_2D.

### Exemple :

          Sub Example_PrependColumn()
          Dim a As Variant, b As variant
              a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((4, 1), (5, 2), (6, 3))
              b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
          End Sub

## PrependRow

Ajouter une nouvelle ligne au bas d'une matrice à deux dimensions. La matrice résultante a les mêmes limites inférieures que la matrice initiale à deux dimensions.

### Syntaxe :

          SF_Array.PrependRow(Array_2D As Variant, Row As Variant) As Variant

### Paramètres :

Array_2D: la matrice préexistante, peut être vide. Si cette matrice a 1 dimension, elle est considérée comme la dernière ligne de la matrice à 2 dimensions résultante.

Row : une matrice à 1 dimension contenant autant d'éléments qu'il y a de lignes dans Array_2D.

### Exemple :

          Sub Example_PrependRow()
          Dim a As Variant, b As variant
              a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((4, 5, 6), (1, 2, 3))
              b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
          End Sub

## RangeInit

Initialiser un nouveau tableau de base zéro avec des valeurs numériques.

### Syntaxe :

          SF_Array.RangeInit(From As [number], UpTo As [number] [, ByStep As [number]]) As Variant

### Paramètres :

From : valeur du premier élément.

UpTo : le dernier élément ne doit pas excéder UpTo.

ByStep : la différence entre deux éléments successifs (par défaut = 1).

### Exemple :

          Sub Example_RangeInit()
          Dim a As Variant
              a = SF_Array.RangeInit(10, 1, -1)
                  ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
          End Sub

## Reverse

Return the reversed one dimension input array.

### Syntaxe :

          SF_Array.Reverse(Array_1D As Variant) As Variant

### Paramètres :

Array_1D : The array to reverse.

### Exemple :

          Sub Example_Reverse()
          Dim a As Variant
              a = SF_Array.Reverse(Array("a", 2, 3, 4))
                  ' (4, 3, 2, "a")
          End Sub

## Shuffle

Return a random permutation of a one dimension array.

### Syntaxe :

          SF_Array.Shuffle(Array_1D As Variant) As Variant

### Paramètres :

Array_1D : The array to shuffle.

### Exemple :

          Sub Example_Shuffle()
          Dim a As Variant
              a = SF_Array.Shuffle(Array(1, 2, 3, 4))
                  ' Unpredictable
          End Sub

## Slice

Return a subset of a one dimension array.

### Syntaxe :

          SF_Array.Slice(Array_1D As Variant, From As Long, [UpTo As Long]) As Variant

### Paramètres :

Array_1D : The array to slice.

From : The lower index in Array_1D of the subarray to extract (From included)

UpTo : The upper index in Array_1D of the subarray to extract (UpTo included). Default = upper bound of Array_1D. If UpTo < From then the returned array is empty.

### Exemple :

          Sub Example_Slice()
          Dim a As Variant
              a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
          End Sub

## Sort

Sort a one dimension array in ascending or descending order. Text comparisons can be case-sensitive or not.
The array must be filled homogeneously, which means that items must be scalars of the same type.
Empty and Null items are allowed. Conventionally Empty < Null < any other scalar value.

### Syntaxe :

          SF_Array.Sort(Array_1D As Variant, SortOrder As String, CaseSensitive As Boolean) As Variant

### Paramètres :

Array_1D : The array to sort.

SortOrder : "ASC" (default) or "DESC".

CaseSensitive : Only for string comparisons, default = False.

### Exemple :

          Sub Example_Sort()
          Dim a As Variant
              a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
                  ' ("A", "B", "C", "a", "b")
          End Sub

## SortColumns

Return a permutation of the columns of a two dimension array, sorted on the values of a given row.
The row must be filled homogeneously, which means that all items must be scalars of the same type.
Empty and Null items are allowed. Conventionally Empty < Null < any other scalar value.

### Syntaxe :

          SF_Array.SortColumns(Array_1D As Variant, RowIndex As Long, SortOrder As String, CaseSensitive As Boolean) As Variant

### Paramètres :

Array_1D : The array to sort.

RowIndex : The index of the row to sort the columns on.

SortOrder : "ASC" (default) or "DESC".

CaseSensitive : Only for string comparisons, default = False.

### Exemple :

          Sub Example_SortColumns()
          -                         | 5, 7, 3 |            ' | 7, 5, 3 |
          -    SF_Array.SortColumns(| 1, 9, 5 |, 2, "ASC") ' | 9, 1, 5 |
          -                         | 6, 1, 8 |            ' | 1, 6, 8 |
          End Sub

## SortRows

Return a permutation of the rows of a two dimension array, sorted on the values of a given column.
The column must be filled homogeneously, therefore all items must be scalars of the same type.
Empty and Null items are allowed. Conventionally Empty < Null < any other scalar value.

### Syntaxe :

          SF_Array.SortRows(Array_1D As Variant, ColumnIndex As Long, SortOrder As String, CaseSensitive As Boolean) As Variant

### Paramètres :

Array_1D : The array to sort.

RowIndex : The index of the column to sort the rows on.

SortOrder : "ASC" (default) or "DESC".

CaseSensitive : Only for string comparisons, default = False.

### Exemple :

          Sub Example_SortRows()
          -                      | 5, 7, 3 |            ' | 1, 9, 5 |
          -    SF_Array.SortRows(| 1, 9, 5 |, 2, "ASC") ' | 5, 7, 3 |
          -                      | 6, 1, 8 |            ' | 6, 1, 8 |
          End Sub

## Transpose

Swap rows and columns in a two dimension array.

### Syntaxe :

          SF_Array.Transpose(Array_2D As Variant) As Variant

### Paramètres :

Array_2D : The array to transpose.

### Exemple :

          Sub Example_Transpose()
          -                       | 1, 2 |  ' | 1, 3, 5 |
          -    SF_Array.Transpose(| 3, 4 |) ' | 2, 4, 6 |
          -                       | 5, 6 |
          End Sub

## TrimArray

Remove from a one dimension array all Null, Empty and zero-length entries.
String items are trimmed with LibreOffice Basic Trim() function.

### Syntaxe :

          SF_Array.TrimArray(Array_1D As Variant) As Variant

### Paramètres :

Array_1D : The array to scan.

### Exemple :

          Sub Example_TrimArray()
          Dim a As Variant
              a = SF_Array.TrimArray(Array("A","B",Null," D "))
                  ' ("A","B","D")
          End Sub

## Union

Build a set, as a zero-based array, by applying the union operator on the two input arrays. Resulting items originate from both arrays.
The resulting array is sorted in ascending order.
Both input arrays must be filled homogeneously, their items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.

### Syntaxe :

          SF_Array.Union(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Paramètres :

Array1_1D : The first input array.

Array2_1D : The second input array.

CaseSensitive : Only if the arrays are populated with strings, default = False.

### Exemple :

          Sub Example_Union()
          Dim a As Variant
              a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("A", "B", "C", "Z", "b")
          End Sub

## Unique

Build a set of unique values derived from the input array.
The input array must be filled homogeneously, its items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.

### Syntaxe :

          SF_Array.Unique(Array_1D As Variant, CaseSensitive As Boolean]) As Variant

### Paramètres :

Array_1D : The input array.

CaseSensitive : Only if the array is populated with texts, default = False.

### Exemple :

          Sub Example_Unique()
          Dim a As Variant
              a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
                  '  ("A", "B", "C", "b")
          End Sub

Toutes les routines ou identificateurs Basic ScriptForge précédés d'un trait de soulignement "_" sont réservés à un usage interne. Ils ne sont pas destinés à être utilisés dans les macros Basic.

Rubriques connexes

Fonctions de matrice

Appel de fonctions Calc

ScriptForge.Dictionary service